Подскажите пожалуйста есть ли такая функция в диджитале “линейка” такого плана как на публичной карте? Если нету то каким образом её сделать, подскажите?
Просто почніть малювати звичайну лінію. В нижньому рядку головного вікна зразу видно її довжину, кут, координати.
Підскажіть будь-ласка хто стикався з такою задачею, треба на графічному материалі та вивести в таблицю відобразити прізвище імя по-батькові та кадастровий номер.
Читайте ВНИМАТЕЛЬНО тему!
БИБЛИОТЕКА ПОЛЕЗНЫХ СКРИПТОВ!!!
Підскажіть на якій сторінці БИБЛИОТЕКИ ПОЛЕЗНЫХ СКРИПТОВ!!! розташований скрипт, який витягує призвище ім’я по-батькові та кадастровий номер з XML на графічну частину карти
у вигляді (на фото)
[attachment=0]XMLReport.dmf[/attachment]
XMLReport.dmf - копія XMLNormal.dmf, але додано кілька параметрів доступних ділянці. Це не скрипт, а те що по телефону обіцяв. Обмеження в одного власника можна уникнути лише скриптом подібним до цього
; Для XML створення пiдписiв вздовж довгої сторони для дiлянок та сумiжникiв
$Obj=0
%BoundCycle
$Obj=@Map.NextSelected $Obj
@If $Obj=0 Then @Goto %End
$CN=
$Layer=@Map.Object[$Obj].LayerID
@If ($Layer<>70005) And ($Layer<>70010) Then @Goto %Next
@If $Layer=70010 Then @Goto %Neighbour
; кадастровий номер
$CN=@Map.Object[$Obj].CalculateFormula Parent[ID7000300](ID70003)Parent[ID7000301](ID70003):Parent[ID7000401](ID70004):P[ID7000513]
;
$Param=@Map.Object[$Obj].Parameter[ID7000520]
$NM=@XML.XPath ProprietorInfo/Authentication/LegalEntity/Name $Param
@If $NM= Then @Goto %NaturalBND
@Goto %DrawText
%NaturalBND
$I=0
%NaturalCycle
$I=$I+1
$NM1=@XML.XPath ProprietorInfo[$I]/Authentication/NaturalPerson/FullName/LastName $Param
$NM2=@XML.XPath ProprietorInfo[$I]/Authentication/NaturalPerson/FullName/FirstName $Param
$NM3=@XML.XPath ProprietorInfo[$I]/Authentication/NaturalPerson/FullName/MiddleName $Param
@If $NM1= Then @Goto %DrawText
@If $NM= Then $NM=$NM1 $NM2 $NM3 Else $NM=$NM,$NM1 $NM2 $NM3
@Goto %NaturalCycle
;
; Сумiжник
%Neighbour
$Param=@Map.Object[$Obj].Parameter[ID7001003]
$NM=@XML.XPath LegalEntity/Name $Param
@If $NM= Then @Goto %NaturalNB
;
@Goto %DrawText
%NaturalNB
$NM1=@XML.XPath NaturalPerson/FullName/LastName $Param
$NM2=@XML.XPath NaturalPerson/FullName/FirstName $Param
$NM3=@XML.XPath NaturalPerson/FullName/MiddleName $Param
$NM=$NM1 $NM2 $NM3
@Goto %DrawText
;
%DrawText
$NumP=@Map.Parameters.FindByID 8000001
@If $NumP>0 Then @Goto %ShowText
$NumP=@Map.Parameters.Add 8000001 5 FullName
;
%ShowText
; додаємо новий параметр з iменем власника
$Param=@Map.Layers.GetValidParameters ID$Layer
$Param=$Param $NumP
@Map.Layers.SetValidParameters ID$Layer $Param
;
; якщо є кадастровий номер, тодi формуємо змiнну для виводу на екран
@If "$CN"<>"" Then $NM=$NM ($CN)
;
@Map.Object[$Obj].Parameter[ID8000001]=$NM
; виводимо надпис на екран
@Map.Object[$Obj].CreateCaption ID8000001 1 0 1 1 0 0
@Map.RefreshObject $Obj
;
%Next
@Goto %BoundCycle
%End
;
Дима, Дякую Вам за розуміння
Підскажіть яким чином перетащить растр в іншу систему координат, якщо при пересчёте видно только контур рамки в новой системе координат, а самого растра нет?
може ви перед ортотрансформацією просто не позначили растр рамкою? …і у вас трасформувалася тому пуста область екрану.
Мається на у вазі що у мене вгс84 перевожу в ск 63 після переводу растра немає а тільки по чотирьом кутам точки (тобто рамка переводиться) а растра нема. Яким чином зробити щоб растр проявився в ск63?
Якщо Сергій Васильович дозволяє, з посиланням на написаний ним скрипт:
Трансформування растрових зображень з однієї системи координат в іншу з можливістю одразу вставити їх в активну карту за посиланням$V=@Version
@If $V>=42881 then @Goto %Start
@Dialog.Message Цей скрипт потребує оновлення програми
@ExecuteMenu HelpAbout
@Break
%Start
$ListDatum=@DatumList
;Тека растрових зображень
$SourceDir=@Dialog.SelectFolder Оберіть теку з растровими зображеннями, які необхідно трансформувати
@If $SourceDir= then @Break Не вказано теку з растровими зображеннями, які необхідно трансформувати
;В який датум трансформувати растри
$DestDatum=
$CountMap=@MapCount
@If $CountMap=0 then $InsertInMap=0
@If $CountMap=0 then @Goto %StartWork
$DestDatum=@Map.Datum
$InsertInMap=@Dialog.Confirm Трансформувати растрові зображення в систему координат $DestDatum і вставити їх за посиланням в активну карту?
@If $InsertInMap=0 then $DestDatum=
%StartWork
@If $DestDatum= then $DestDatum=@Dialog.ListSelect Виберіть датум, в який слід трансформувати растрові зображення|$ListDatum
@If $DestDatum= then @Break Не вказано датум, в який слід трансформувати растрові зображення
;Датум растрових зображень на замовчування
$GetImageDatum=@Dialog.ListSelect В якій системі координат вхідні растрові зображення?|$ListDatum
@If $GetImageDatum= then @Break Не вказано датум растрових зображень на замовчування
@SetDefaultImageDatum $GetImageDatum
;Отримання списку файлів растрових зображень
$L=@Calc length("$SourceDir")
$DestSubDir=@Calc Replace("$DestDatum","/","-",1)
$DestSubDir=@DequoteText $DestSubDir
$DestDir=$SourceDir ($DestSubDir)
@Text[2].Clear
@Text[1].FolderListTree *.tif $SourceDir
$FC=@Text[1].Count
@if $FC=0 then @Break Не знайдено tif-файлів у теці $SourceDir
@Text[2].Add Тека з вхідними зображеннями: $SourceDir
@Text[2].Add Тека із трансформованими зображеннями: $DestDir
@Text[2].Add Трансформовані зображення:
$I=0
%LoopFile
$I=$I+1
@FileNew
@Map.Datum $DestDatum
$FN=@Text[1].Line[$I]
$GSD=@GetImageGSD $FN
$BPP=3
$BPP2=@GetImageBitsPerPixel $FN
@if $BPP2=8 then $BPP=1
@Map.InsertTriangulation $FN
$RP=@Calc copy("$FN",$L+2,1000)
$RP=@DequoteText $RP
$PC=@StringPartCount \ $RP
$SF=
@if $PC<2 then @Goto %Continue1
$J=1
%LoopPart
$SF2=@StringPart $J\$RP
@if $SF2<> then $SF=$SF\$SF2
$J=$J+1
@if $J<$PC then @Goto %LoopPart
%Continue1
@OrthoRectification $GSD $BPP $DestDir$SF
@CloseMap
@Text[2].Add Трансформовано $FN
@Goto %Continue2
%IgnoreRaster
@Text[2].Add Проблема з обробкою $FN
%Continue2
@CloseMap
@if $I<$FC then @Goto %LoopFile
;Вставка растрів за посиланням в активну карту
@If $InsertInMap=0 then @Goto %EndRecalculateImage
@Map.InsertRasters $DestDir\*.tif
@Window.ShowSelected
@Map.Selected.SendToBack
%EndRecalculateImage
@Text[2].Save $SourceDir\OrthoRect.log
@Run notepad.exe $SourceDir\OrthoRect.log
@Run $DestDir
Возможно кто нибудь сталкивался с ситуацией: кадастровый план предположим в масштабе 1:25000, нужно чтобы был в 1:10000 масштабе. При копировании 1:25000 и через специальную вставку в другом масштабе вставляю в масштаб 1:10000 то промеры разлитаются от границы участка, каким образом сделать чтобы промеры и буквы на смежниках не разлитались от границы участка??
Сергей Олейник, Вы писали о команде Run, хотел уточнить каким образом она работает. Так как описано у Вас у меня не получается. Можна описать по шагово что за чем…
Я создаю панель, кнопку, и вставляю Run и файл внешеней программы к примеру autocad.exe или другой exe-файл, после этого не чего не происходит (не запускается)??? Возможно что то не так делаю…!
Шановний Vladimirart08! Ви хочете отримати відповідь? Вам скільки раз відповідали - НЕ В ТЕМІ БІБЛІОТЕКА СКРИПТІВ!!! Ну, ніякої поваги - так ніякої відповіді від форумчан.
Дякую за розуміння.
voha я Вас розумію, але Ви гуру диджитала, а я тільки вчусь, по вашій відмові в допомозі я розумію що Ви не знаєте як вирішити питання, а також не можете підсказати до якого розділу форума звернутися?
Маленький бонус, щоб не було скучно пiд час карантину 
Хрестики-нулики в Digitals/Delta XE
підкажіть чи можливо таке реалізувати скриптом:
з поточної карти в виділеному слої скопіювати таблицю з координатами і вставити в текстовий файл. Буду дуже вдячний. Самостійно розібратися не получається.
Скрипт викликає Сервіс-Документи-Шаблон…
попередньо отримавши в текстовий файл координати ділянки в МСК-хх
$AM=@ActivateMap
@if $AM=0 then @Break
@Map.DeselectAll
@Map.SelectLayer ID70005
$SO=@Map.SelectedObject
@if $SO=0 then @Break
$PPath=@ProgramPath
$ActiveMSK=@ActiveMSK
$Datum=@Map.Datum
$CadNum=@Map.XMLCadastralNumber
@Map.Copy
@FileNew $PPath\Temp.dmf /Template=XMLNormal.dmf
@Map.Paste
$ParcelObj=@Map.SelectedObject
;@ExecuteMenu CoordinatesLengthsDirsInternals1
;$Tab63Obj=@Map.SelectedObject
;$Tab63=@Map.Object[$Tab63Obj].TableText
;@Text[1].Clear
;@Text[1].Text $Tab63
;@Text[1].Save $PPath\Vedomost63.txt
@Map.Datum $Datum
@Map.RecalculateToNewDatum $Datum $ActiveMSK
@Map.DeselectAll
@Map.SelectObject $ParcelObj
@ExecuteMenu CoordinatesLengthsDirsInternals1
$TabMSKObj=@Map.SelectedObject
$TabMSK=@Map.Object[$TabMSKObj].TableText
@Text[1].Clear
@Text[1].Text $TabMSK
@Text[1].Add $ActiveMSK
@Text[1].Save $PPath\VedomostMSK.txt
@CloseMap
@ActivateMap $AM
Документы | <DZK_Vedomost>